易语言- 定义一个系统范围的热键 RegisterHotKey UnregisterHotKey

.版本 2

.DLL命令 UnregisterHotKey, 整数型, , “UnregisterHotKey”
    .参数 hWnd, 整数型
    .参数 HotKeyID, 整数型

.DLL命令 RegisterHotKey, 整数型, “user32.dll”, “RegisterHotKey”
    .参数 hWnd, 整数型
    .参数 id, 整数型
    .参数 fsModifoers, 整数型
    .参数 vk, 整数型

.DLL命令 SetWindowLongA, 子程序指针, , “SetWindowLongA”
    .参数 hWnd, 整数型
    .参数 nIndex, 整数型
    .参数 dwNewLong, 子程序指针

.DLL命令 CallWindowProcA, 整数型, , “CallWindowProcA”
    .参数 lpPrevWndFunc, 子程序指针
    .参数 hWnd, 整数型
    .参数 Msg, 整数型
    .参数 wParam, 整数型
    .参数 lParam, 整数型

.DLL命令 _控制鼠标, , “user32”, “mouse_event”
    .参数 dwFlags, 整数型
    .参数 dx, 整数型
    .参数 dy, 整数型
    .参数 cButtons, 整数型
    .参数 dwExtraInfo, 整数型

.版本 2

.程序集 热键程序集
.程序集变量 父窗口句柄, 整数型
.程序集变量 默认窗口程序, 子程序指针
.程序集变量 热键数量, 整数型
.程序集变量 状态键数组, 整数型, , “0”
.程序集变量 主键数组, 整数型, , “0”
.程序集变量 处理热键子程序数组, 子程序指针, , “0”

.子程序 RegHotKey, 整数型, 公开, 注册成功返回热键ID,失败返回0
.参数 窗口句柄, 整数型
.参数 功能键状态, 整数型, , 1、Alt；2、Ctrl；4、Shitf；8、Win。若要两个或以上的状态键按则把它们的值相加.
.参数 键代码, 整数型
.参数 子程序指针, 子程序指针
.局部变量 HotKeyID

HotKeyID ＝ RegisterHotKey (窗口句柄, 热键数量 ＋ 1, 功能键状态, 键代码)
.如果真 (HotKeyID ≠ 0)
    热键数量 ＝ 热键数量 ＋ 1
    加入成员 (状态键数组, 功能键状态)
    加入成员 (主键数组, 键代码)
    加入成员 (处理热键子程序数组, 子程序指针)
    .如果真 (热键数量 ＝ 1)
        默认窗口程序 ＝ SetWindowLongA (窗口句柄, -4, &新窗口程序)
    .如果真结束
    返回 (热键数量)
.如果真结束
返回 (0)

.子程序 新窗口程序, 整数型
.参数 窗口句柄, 整数型
.参数 消息, 整数型
.参数 参数1, 整数型
.参数 参数2, 整数型

.如果真 (消息 ＝ 786)
    返回 (CallWindowProcA (处理热键子程序数组 [参数1], 窗口句柄, 消息, 参数1, 参数2))  ‘ 把需要处理的消息传递给处理程序
.如果真结束
返回 (CallWindowProcA (默认窗口程序, 窗口句柄, 消息, 参数1, 参数2))  ‘ 把不需要处理的消息传递给默认窗口处理程序，使窗口能正常响应消息

.子程序 UnRegHotKey, 整数型, 公开, 成功返回非0,失败返回0
.参数 窗口句柄, 整数型
.参数 HotKeyID, 整数型

返回 (UnregisterHotKey (窗口句柄, HotKeyID))